Есть ли способ обращения к полям указателя на запись из ASM?

[Cheb]

Сабж. Есть указатель на запись. Надо из блока ASM влезть в одно из его полей.
Применяю хак: объявляю дополнительную переменную, в которую записываю адрес.
Неэлегантно. Бесит.

Код: Выделить всё

  procedure _AllocateThreadExceptionState(thread_title: PUnicodeChar); cdecl;
  var
    pes: PMotherSehState;
    ssaddr: ptruint;
  begin
   //no try block. If *this* simplest thing crashes it means things are already FUBAR.
    pes:= GetExceptionState();
    FillChar(pes^, sizeof(pes^), 0);
    pes^.ThreadId:= GetCurrentThreadId();
    pes^.IsModuleThread:= true;
    if Assigned(thread_title) then pes^.ThreadTitle:= PUnicodeCharToUnicodeString(thread_title);

    ssaddr:= ptruint(@pes^.StackSegment);
    {$ifdef cpu64}
      asm
        push ax
        push rsi
        mov rsi, qword[ssaddr]
        mov ax, ss
        mov word[rsi], ax
        pop rsi
        pop ax
      end;
    {$else}
      asm
        push ax
        push esi
        mov esi, dword[ssaddr]
        mov ax, ss
        mov word[esi], ax
        pop esi
        pop ax
      end;
    {$endif}
  end; 

[Лекс Айрин]

Cheb, на полноценном асме точно есть. Это адресация относительно начала записи. Но, естественно, надо знать это смещение. Не элегантный способ имхо проще.

[Sergei I. Gorelkin]

Компилятор вполне понимает "ТипЗаписи.ИмяПоля" в качестве смещения операндов ассемблера.

Но можно и вот так:

Код: Выделить всё

function get_ss: word; assembler; nostackframe;
asm
   mov ax, ss
end;

...
pes^.stacksegment := get_ss;
...

[Cheb]

Спасибо!